Arduino + NRF24L01: Simple Bidirectional Wireless Communication

Per circuit, you will be needing following elements:

• Arduino board, I will be using an Arduino Nano with the ATmega328 chip.
• nRF24L01 transmitter.
• 2 LEDs, one green and one red.
• A button.
• 3 Resistors (depends on your LEDs, but probably about 200-1000 Ohm).
• (Optional, but very helpful) Breadboard.

IMPORTANT: You can use the normal 5V digital pins for the input pins of the nRF24L01, but you must use the 3.3V pin as input power source. If you use 5V instead, you will probably burn the chip, since 5V is outside of its 1.9 to 3.6V supply range.

The Arduino nano to nRF24L01 pin connection is as follows (note that you may need to connect it differently if you use a different arduino board, refer to the RadioHead library):

• VCC - 3.3V
• GND - GND
• CE - D8
• CSN - D10
• SCK - D13
• MOSI - D11
• MISO - D12
• IRQ - Not connected

Further, I use D5 for the button, D4 for the red LED and D3 for the green one, each connected with a 220 Ohm resistor.

To power the arduino boards, you can connect them to a USB port or to a 9V battery (Battery negative to GND and positive to VIN).

Download the RadioHead Library and install it.

Upload this code to each of the arduino boards:

#include <SPI.h>
#include <RH_NRF24.h>
// Singleton instance of the radio driver
RH_NRF24 nrf24;
int greenLed = 3;
int redLed = 4;
int button = 5;
void setup() 
{
  Serial.begin(9600);
  pinMode(greenLed, OUTPUT);
  pinMode(redLed, OUTPUT);
  pinMode(button, INPUT);
  while (!Serial) 
    ; // wait for serial port to connect. Needed for Leonardo only
  if (!nrf24.init())
    Serial.println("init failed");
  // Defaults after init are 2.402 GHz (channel 2), 2Mbps, 0dBm
  if (!nrf24.setChannel(1))
    Serial.println("setChannel failed");
  if (!nrf24.setRF(RH_NRF24::DataRate2Mbps, RH_NRF24::TransmitPower0dBm))
    Serial.println("setRF failed");    
}
void loop()
{
  if (digitalRead(button)) {
    //button is pressed, message should be sent, turn the green LED on
    digitalWrite(greenLed, HIGH);    
   // Send a message
    uint8_t data[] = "Aloha";
    nrf24.send(data, sizeof(data));
    nrf24.waitPacketSent();
    digitalWrite(greenLed, LOW);
  } else {
    // Wait for a message
    uint8_t buf[RH_NRF24_MAX_MESSAGE_LEN];
    uint8_t len = sizeof(buf);
    while (nrf24.waitAvailableTimeout(200) && nrf24.recv(buf, &len))
    {   
        //something was received, turn the right LED on
        digitalWrite(redLed, HIGH);      
    }      
    digitalWrite(redLed, LOW);    
  }
}